Auto spawn blobs?

Since you can't attach scripts to tiles, you will most likely want to use a rules script for the timer, checking and spawning. Below is a working example of your request, it iterates through every tile on the map checking for your conditions. If those conditions are found it adds that position to an array, then it will iterate through all those positions and spawn a fishy.

Code:

// LeftCornerFish.as

const uint tickRate = 10 * getTicksASecond();

void onTick(CRules@ this)
{
    if (getGameTime() % tickRate == 0)
    {
        print("fishy time!");

        CMap@ map = getMap();
        if (map !is null)
        {
            Vec2f[] tiles;

            float tileSize = map.tilesize;

            uint mapWidth = map.tilemapwidth;
            uint mapHeight = map.tilemapheight;
            uint totalTileSpaces = mapWidth * mapHeight;

            for (uint i = 0; i < totalTileSpaces; i++)
            {
                TileType cent = map.getTile(i).type;
                TileType down = map.getTile(i + mapWidth).type;
                TileType left = map.getTile(i - 1).type;

                if (cent == CMap::tile_empty && down == CMap::tile_ground && left == CMap::tile_ground)
                {
                    Vec2f position = map.getTileWorldPosition(i);
                    tiles.push_back(position);
                }
            }

            for (uint i = 0; i < tiles.length; i++)
            {
                if (getNet().isServer())
                {
                    CBlob@ blob = server_CreateBlob("fishy", -1, tiles[i]);
                }
            }
        }
    }
}

Do note this isn't a solution but an example.

 

Made some minor changes for readability and efficiency, I also added a bool that checks the spawning position for static blobs (note: you can easily expand the conditions of the bool).

Code:

// LeftCornerFish.as

const uint tickRate = 10 * getTicksASecond();

void onTick(CRules@ this)
{
    if (getGameTime() % tickRate == 0)
    {
        print("fishy time!");

        CMap@ map = getMap();
        if (map !is null)
        {
            float tileSize = map.tilesize;

            uint mapWidth = map.tilemapwidth;
            uint mapHeight = map.tilemapheight;
            uint totalTileSpaces = mapWidth * mapHeight;

            for (uint i = 0; i < totalTileSpaces; i++)
            {
                TileType cent = map.getTile(i).type;
                TileType down = map.getTile(i + mapWidth).type;
                TileType left = map.getTile(i - 1).type;

                if (cent == CMap::tile_empty && down == CMap::tile_ground && left == CMap::tile_ground)
                {
                    Vec2f pos = map.getTileWorldPosition(i) + (Vec2f(tileSize, tileSize) * 0.5f);
                    print("position = " + pos.x + ", " + pos.y);
                    if (getNet().isServer() && canSpawnAtPosition(map, pos))
                    {
                        CBlob@ blob = server_CreateBlob("fishy", -1, pos);
                    }
                }
            }
        }
    }
}

bool canSpawnAtPosition(CMap@ map, Vec2f pos)
{
    CBlob@[] overlapping;
    map.getBlobsAtPosition(pos, @overlapping);
    for (uint i = 0; i < overlapping.length; i++)
    {
        if (overlapping[i].getShape().isStatic())
        {
            return false;
        }
    }
    return true;
}

 

it means that you're trying to call a function that doesn't exit. The function getBlobsAtPosition(Vec2f, CBlob@[]@) is relatively "new", you might want to run forceupdate.bat to ensure you have the latest version of King Arthur's Gold.

 

Can you give me some more detail exactly what you want to accomplish, I might be able to come up with a better solution for you.

 

@Monkey_Feats: it's going to require an array of bools (true/false values) that is initialised to the size of the map, and all false, and set true each time something is spawned there.

Code:

//create and initialise the array (might want to store the array
//at global scope for easy access, otherwise using rules.set/get)
//the array is set up to use the same indexing as the tilemap
//so if we have a tile index (like in skinneys example script),
//we can use it to check if something has spawned
CMap@ map = getMap();
array<bool> has_spawned;
int tilemapsize = map.tilemapwidth * map.tilemapheight;
has_spawned.resize(tilemapsize);
for(int i = 0; i < tilemapsize; i++)
    has_spawned[i] = false;

//using some tile index i, like in skinney's "for (uint i = 0; i < totalTileSpaces; i++)"
if(!has_spawned[i] && ( /*all your other conditions here*/ ))
{
    has_spawned[i] = true;
    /*
        do spawning here.
    */
}

I've tried to give an example you need to do a bit of piecing together to work with - this is meant to be educational and show you how you'd go about doing that, rather than give you a copy-and-paste solution :)

glad to see you getting interested in programming/modding.