Winning Sound ?!

teamNum == 1 ? Sound::Play("/RedTeamWin.ogg") : Sound::Play("/BlueTeamWin.ogg"); and the same again for the lose sound

 

I'm not sure that'd work, the cleaner way is

Code:

Sound::Play(teamNum == 0 ? "/BlueTeamWin.ogg" : "/RedTeamWin.ogg");

If you want to call different functions you'd use an if block, ternary operators are kind of inappropriate else.

also damn you ninja

 

oh yeah thought it looked wrong

--- Double Post Merged, May 12, 2017, Original Post Date: May 12, 2017 ---

If you have more than 2 teams you could make a couple arrays. @AsuMagic back me up here, I'm almost always wrong.

Code:

void onTick(CRules@ this)
{
    if (this.isGameOver() && this.getTeamWon() >= 0 && !this.get_bool(tagname))
    {
        // only play for winners
        CPlayer@ localplayer = getLocalPlayer();
        if (localplayer !is null)
        {
            CBlob@ playerBlob = getLocalPlayerBlob();
            int teamNum = playerBlob !is null ? playerBlob.getTeamNum() : localplayer.getTeamNum() ; // bug fix (cause in singelplayer player team is 255)
            if (teamNum == this.getTeamWon())
            {
                string winsound = getWinSound(teamNum);
                Sound::Play(winsound +".ogg");
            }
            else
            {
                string losesound = getLoseSound(teamNum);
                Sound::Play(losesound +".ogg");
            }
        }

        this.set_bool(tagname, true);
        // no sound played on spectator or tie
    }
}

string getWinSound(u8 team)
{   
    string winsound = "";
    string[] teamSounds = { "/blueteamwin",
                            "/redteamwin",
                            "/greenteamwin",
                            "/purpleteamwin",
                            "/orangeteamwin",
                            "/aquateamwin",
                            "/tealteamwin",
                         };

     for (uint i = 0; i < teamSounds.length; i++)
    {
        if (i == team)
        {
            winsound = teamSounds[i];
        }
    }
    return winsound;
}

string getLoseSound(u8 team)
{   
    string losesound = "";
    string[] teamSounds = { "/blueteamlose",
                            "/redteamlose",
                            "/greenteamlose",
                            "/purpleteamlose",
                            "/orangeteamlose",
                            "/aquateamlose",
                            "/tealteamlose",
                         };

     for (uint i = 0; i < teamSounds.length; i++)
    {
        if (i == team)
        {
            losesound = teamSounds[i];
        }
    }
    return losesound;
}

 

Your for loop is quite useless, you simply can access the string at index team. If you're worrying about accessing a string out of bounds you can just check the size of the array. (It won't be necessary to check for the index to be negative because team is unsigned and the subscript operator likely takes an unsigned anyways)
The winsound variable you have is unnecessary and will perform useless extra copies. You can return directly the string at the index you want and return "" or "/blueteamwin" as a default.
I don't think length is a public field, it is a function that has to be called (i.e. length()). I typically use size(), which does the same thing, but is apparently more conventional in the KAG code base (it's the member function you'd have in C++).

Generally I'd have done this :

Code:

void onTick(CRules@ this)
{
    if (this.isGameOver() && this.getTeamWon() >= 0 && !this.get_bool(tagname))
    {
        // only play for winners
        CPlayer@ localplayer = getLocalPlayer();
        if (localplayer !is null)
        {
            CBlob@ playerBlob = getLocalPlayerBlob();
            int teamNum = playerBlob !is null ? playerBlob.getTeamNum() : localplayer.getTeamNum() ; // bug fix (cause in singelplayer player team is 255)
            Sound::Play("/" + getTeamName(teamNum) + "team" + (teamNum == this.getTeamWon() ? "win" : "lose") + ".ogg");
        }

        this.set_bool(tagname, true);
        // no sound played on spectator or tie
    }
}

string getTeamName(u8 team)
{ 
    string[] teamNames =
    {
        "blue",
        "red",
        "green",
        "purple",
        "orange",
        "aqua",
        "teal",
    };

    if (team < teamSounds.size())
        return teamNames[team];
    else
        return "default";
}

This way, it would use blueteamwin.ogg, redteamwin.ogg, greenteamlose.ogg, etc.
The CTeam class also can let you use its getName() method, but it returns something like Blue Team or Red Team. The advantage would be an extra function removed, but it needs a bit of string manipulation - lower out the string and replace " " by "" (or by "_").
See:

Code:

[09:33:41] print(string("hello world hOW aRe yOu doing").replace(" ", "").toLower());
[09:33:41] helloworldhowareyoudoing

This gives the final code :

Code:

void onTick(CRules@ this)
{
    if (this.isGameOver() && this.getTeamWon() >= 0 && !this.get_bool(tagname))
    {
        // only play for winners
        CPlayer@ localplayer = getLocalPlayer();
        if (localplayer !is null)
        {
            CBlob@ playerBlob = getLocalPlayerBlob();
            int teamNum = playerBlob !is null ? playerBlob.getTeamNum() : localplayer.getTeamNum() ; // bug fix (cause in singelplayer player team is 255)
            CTeam@ team = this.getTeam(teamNum);
            string team_name = team.getName().replace(" ", "").toLower();
            Sound::Play("/" + team_name + (teamNum == this.getTeamWon() ? "win" : "lose") + ".ogg");
        }

        this.set_bool(tagname, true);
        // no sound played on spectator or tie
    }
}

Also, team names depends on the configuration. So if you have the green team named "Orc Team", the filename will be "orcteamwin.ogg" for the winning sound. If it's just "Orcs", "orcswin.ogg", etc.

 

Nice one. :)